system "Normy EC test system.dgt"
// follow the winner in last 5 hits
method "main"
begin
    while starting a new session
    begin
        call "init"
    end
    call "win/loss"
    call "tracking"
end

// ----------------------------------------------------------
method "win/loss"
begin
    if bankroll >= record "HighestBR" data
    begin
        Put 100% of bankroll to record "HighestBR" data
        put 1 to record "Progression" data
        put 100% of record "HighestBR" data to record "5 points" Data
        subtract 5 from record "5 points" Data
        if bankroll >= 5
        begin
            stop session
        end
    end

    if bankroll <= record "5 points" data
    begin
        add 1 to record "Progression" data
        subtract 5 from record "5 points" Data
    end
end

// ------------------------------INITIALIZATION-------------------------------
method "init"
begin
    copy list [1,3,5,7,9,12,14,16,18,19,21,23,25,27,30,32,34,36]to record "RED#" layout;
    copy list [2,4,6,8,10,11,13,15,17,20,22,24,26,28,29,31,33,35]to record "BLACK#" layout;
    copy list [number 0] to record "zero" layout
    put 0 to record "red count" Data
    put 0 to record "blk count" Data
    put 0 to record "5 points" Data
    put 1 to record "Progression" data
    Put 0 to record "HighestBR" data
   
    set flag "skip1stSpin" to false
end
// ----------------------------------------------------------
method "tracking"
begin
    if flag "skip1stSpin" is true
    begin
        copy last number to record "last spin" layout;
        if  record "last spin" layout is not found in record "zero" layout
        begin
            Track Last Number for 5 times to record "tracked numbers" layout
        end
       
        if record "tracked numbers" layout count < 5
        begin
            exit
        end
       
        clear record "red count" Data
        clear record "blk count" Data
        put 1 on record "tracked numbers" layout index
       
        loop until record "tracked numbers" layout index > record "tracked numbers" layout count
        begin
            if record "tracked numbers" layout is found in record "RED#" layout
            begin
                add 1 to record "red count" Data
            end

            if record "tracked numbers" layout is found in record "BLACK#" layout
            begin
                add 1 to record "blk count" Data
            end
            add 1 to record "tracked numbers" layout index;
        end

        if record "red count" Data > record "blk count" Data
        begin
            put 100% of record "Progression" Data on red
        end
        if record "blk count" Data > record "red count" Data
        begin
            put 100% of record "Progression" Data on black
        end
    end
set flag "skip1stSpin" to true
end